BlitzMax provides limited support for a form of runtime reflection.

Using reflection, programs can 'inspect' objects and types at runtime. You can determine the fields and methods contained in an object or type, set and get object fields and invoke - or 'call' - object methods.

To use reflection, you first need a TTypeId object. TTypeId objects correspond to BlitzMax user defined types, and there is a single TTypeId object for every user defined type in the program. There are also TTypeId objects for the 'primitive' types - byte, short, int, long, float, double and string. TTypeId objects are returned by the TTypeId.ForName and TTypeId.ForObject functions.

Once you have a TTypeId object, you can inspect the fields and methods of a user defined type using the EnumFields and EnumMethods methods. These methods return TField and TMethod objects that describe the fields and methods within the type. For example:


Type TMyType
Field x,y,z
End Type

Local id:TTypeId=TTypeId.ForName( "TMyType" )

For Local fld:TField=EachIn id.EnumFields()
Print fld.Name()+":"+fld.TypeId().Name()

This simple program will print "x:Int", "y:Int" and "z:Int" - the names and types of the fields within TMyType. Note that this is done without actually creating a new TMyType.

The following example sets the fields of an object:


Type TMyType
Field x,y,z
End Type

Local obj:TMyType=New TMyType
Local id:TTypeId=TTypeId.ForObject( obj )

For Local fld:TField=EachIn id.EnumFields()
fld.Set obj,String( Rand(10) )

Print obj.x+","+obj.y+","+obj.z

In this case we need an actual instance of TMyType, otherwise we have nothing to set the fields of! Also, we have used TTypeId.ForObject instead of TTypeId.ForName to get a TTypeId. While in this case TTypeId.ForName could have been used to achieve the same result, in general we may not know the exact type of the object, and therefore we wont know its type name.

Also note that the code that actually sets the fields uses String( Rand(10) ). This is because the Set method takes an object - but our fields are ints! BlitzMax reflection deals with this by using strings to represent numeric types. The same rule applies to the Get method. Any numeric fields will be returned as strings which you must then convert to the appropriate type if necessary.

Finally, let's invoke an object method:


Type TMyType
Method Update( t# )
Print "TMyType.Update:"+t
End Method
End Type

Local obj:TMyType=New TMyType
Local id:TTypeId=TTypeId.ForObject( obj )

Local update:TMethod=id.FindMethod( "Update" )

update.Invoke obj,[String( .25 )]

This example uses FindMethod to locate a type method and Invoke to call it. Arguments to the method are contained in an object array, and again the float argument is converted to a string.

In addition to the TTypeId, TField and TMethod types, the BlitzMax reflection module also declares a number of global TTypeId objects:

  • ByteTypeId
  • ShortTypeId
  • IntTypeId
  • LongTypeId
  • FloatTypeId
  • DoubleTypeId
  • StringTypeId
  • ObjectTypeId

These may be used instead of the corresponding TTypeId.ForName call. For example, TTypeId.ForName( "Int" ) and IntTypeId will return the same object.

Globals edit

ByteTypeId edit

Global ByteTypeId:TTypeId=New TTypeId.Init( "Byte",1 )

Description: Primitive byte type

ShortTypeId edit

Global ShortTypeId:TTypeId=New TTypeId.Init( "Short",2 )

Description: Primitive short type

IntTypeId edit

Global IntTypeId:TTypeId=New TTypeId.Init( "Int",4 )

Description: Primitive int type

LongTypeId edit

Global LongTypeId:TTypeId=New TTypeId.Init( "Long",8 )

Description: Primitive long type

FloatTypeId edit

Global FloatTypeId:TTypeId=New TTypeId.Init( "Float",4 )

Description: Primitive float type

DoubleTypeId edit

Global DoubleTypeId:TTypeId=New TTypeId.Init( "Double",8 )

Description: Primitive double type

StringTypeId edit

Global StringTypeId:TTypeId=New TTypeId.Init( "String",4,bbRefStringClass() )

Description: Primitive string type

ObjectTypeId edit

Global ObjectTypeId:TTypeId=New TTypeId.Init( "Object",4,bbRefObjectClass() )

Description: Primitive object type

ArrayTypeId edit

Global ArrayTypeId:TTypeId=New TTypeId.Init( "Null[]",4,bbRefArrayClass() )

Description: Primitive array type

Types edit

TMember edit

Type member - field or method.

  • Name
  • TypeId
  • MetaData

TMember: Methods edit


Method Name$()

Description: Get member name


Method TypeId:TTypeId()

Description: Get member type


Method MetaData$( key$="" )

Description: Get member meta data

TField edit

Type field

  • Get
  • GetInt
  • GetLong
  • GetFloat
  • GetDouble
  • GetString
  • Set
  • SetInt
  • SetLong
  • SetFloat
  • SetDouble
  • SetString

TField: Methods edit


Method Get:Object( obj:Object )

Description: Get field value


Method GetInt:Int( obj:Object )

Description: Get int field value


Method GetLong:Long( obj:Object )

Description: Get long field value


Method GetFloat:Float( obj:Object )

Description: Get float field value


Method GetDouble:Double( obj:Object )

Description: Get double field value


Method GetString$( obj:Object )

Description: Get string field value


Method Set( obj:Object,value:Object )

Description: Set field value


Method SetInt( obj:Object,value:Int )

Description: Set int field value


Method SetLong( obj:Object,value:Long )

Description: Set long field value


Method SetFloat( obj:Object,value:Float )

Description: Set float field value


Method SetDouble( obj:Object,value:Double )

Description: Set double field value


Method SetString( obj:Object,value$ )

Description: Set string field value

TMethod edit

Type method

  • ArgTypes
  • Invoke

TMethod: Methods edit


Method ArgTypes:TTypeId[]()

Description: Get method arg types


Method Invoke:Object( obj:Object,args:Object[] )

Description: Invoke method

TTypeId edit

Type id

  • Name
  • MetaData
  • SuperType
  • ArrayType
  • ElementType
  • ExtendsType
  • DerivedTypes
  • NewObject
  • Fields
  • Methods
  • FindField
  • FindMethod
  • EnumFields
  • EnumMethods
  • NewArray
  • ArrayLength
  • ArrayDimensions
  • GetArrayElement
  • SetArrayElement
  • ForName
  • ForObject
  • EnumTypes

TTypeId: Methods edit


Method Name$()

Description: Get name of type


Method MetaData$( key$="" )

Description: Get type meta data


Method SuperType:TTypeId()

Description: Get super type


Method ArrayType:TTypeId(dims:Int = 1)

Description: Get array type


Method ElementType:TTypeId()

Description: Get element type


Method ExtendsType( typeId:TTypeId )

Description: Determine if type extends a type


Method DerivedTypes:TList()

Description: Get list of derived types


Method NewObject:Object()

Description: Create a new object


Method Fields:TList()

Description: Get list of fields

Information: Only returns fields declared in this type, not in super types.


Method Methods:TList()

Description: Get list of methods

Information: Only returns methods declared in this type, not in super types.


Method FindField:TField( name$ )

Description: Find a field by name

Information: Searchs type hierarchy for field called name.


Method FindMethod:TMethod( name$ )

Description: Find a method by name

Information: Searchs type hierarchy for method called name.


Method EnumFields:TList( list:TList=Null )

Description: Enumerate all fields

Information: Returns a list of all fields in type hierarchy


Method EnumMethods:TList( list:TList=Null )

Description: Enumerate all methods

Information: Returns a list of all methods in type hierarchy - TO DO: handle overrides!


Method NewArray:Object( length, dims:Int[] = Null )

Description: Create a new array


Method ArrayLength( array:Object, dim:Int = 0 )

Description: Get array length


Method ArrayDimensions:Int( array:Object )

Description: Get the number of dimensions


Method GetArrayElement:Object( array:Object,index )

Description: Get an array element


Method SetArrayElement( array:Object,index,value:Object )

Description: Set an array element

TTypeId: Functions edit


Function ForName:TTypeId( name$ )

Description: Get Type by name


Function ForObject:TTypeId( obj:Object )

Description: Get Type by object


Function EnumTypes:TList()

Description: Get list of all types