Summary

Licensing

I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue

Maxima CAS src code

• ListOfCriticalPoints = [(- 0.5574028094466224 %i) - 0.7341195567603783, 0.3241998748996613 %i - 0.5938111474337146, 0.3239311106009048 - 0.4918402540438871 %i, 0.4050431885908482 %i + 0.3639995935931879]
• fixed points : [(- 0.4 %i) - 0.8, 0.0] with stability_list = [1.025280449438104, 1.0]
• (- 0.5574028094466224 %i) - 0.7341195567603783 is escaping
• 0.3241998748996613 %i - 0.5938111474337146 is not escaping
• 0.3239311106009048 - 0.4918402540438871 %i is not escaping
• 0.4050431885908482 %i + 0.3639995935931879 orbit is not escaping

/*



*/


kill(all);
remvalue(all);


/*------------- functions definitions ---------*/

/* function */
f(z):=z^5 +(0.8+0.4*%i)*z^4 + z;


/* multiplier */
define(multiplier(z), diff(f(z),z,1));


stability(z):=
block(
	[s],
	s:multiplier(z),
	s: rectform(s),
	s: float(s),
	s: cabs(s),
	return(s)
)$




GiveListOfCriticalPoints(fun):=
block(
  [d,s],
  /* derivative */
  d:diff(fun,z,1),
  /* critical points z: d=0 */
  s:solve(d=0,z),
  /* remove "z="  from list s */
  s:map('rhs,s),
  /* convert to form x+y*%i */
  s:map('rectform,s),
  s:map('float,s),
  return(s)
)$



/* f(z) is used as a global function
   I do not know how to put it as a argument */

GiveOrbit(z0,OrbitLength):=
block(
 [z,Orbit],
 z:z0,
 Orbit:[z], 
 for i:1 thru OrbitLength step 1 do
        ( z:expand(f(z)),
         if cabs(z) > 2 then 
         	( print(z0), print("orbit of is escaping"),  
         	  return(Orbit)),
          Orbit:endcons(z ,Orbit)
          ),
 print(z0), print("orbit is not escaping"),  
 return(Orbit) 

)$

/* find fixed points  returns a list */
GiveFixedPoints():= block
(
  [s],
  s:solve(f(z)=z),
  /* remove "z="  from list s */
  s:map('rhs,s),
  s:map('rectform,s),
  s:map('float,s),
  return(s)
)$



/* 
converts complex number z = x*y*%i 
to the list in a draw format:  
[x,y] 
*/
d(z):=[float(realpart(z)), float(imagpart(z))]$

ToPoint(z):= points([d(z)])$

/* give Draw List from one point*/
dl(z):=[d(z)]$

ToPoints(myList):= points(map(d,myList))$





compile(all);

/* ------------  */

iLength:6000;


ListOfCriticalPoints:GiveListOfCriticalPoints(f(z))$
multiplicities;
ListOfCriticalPoints;



fixed :GiveFixedPoints();


stability_list : map(stability, fixed);


OrbitEscaping: GiveOrbit(ListOfCriticalPoints[1],iLength)$

Orbit2: GiveOrbit(ListOfCriticalPoints[2],iLength)$
Orbit3: GiveOrbit(ListOfCriticalPoints[3],iLength)$
Orbit4: GiveOrbit(ListOfCriticalPoints[4],iLength)$



/* fixed: ToPoints(fixed)$ */
f1: ToPoint(fixed[1]);
f2: ToPoint(fixed[2]);

OrbitEscaping : ToPoints(OrbitEscaping)$
Orbit2 : ToPoints(Orbit2)$
Orbit3 : ToPoints(Orbit3)$
Orbit4 : ToPoints(Orbit4)$


cr1: ToPoint(ListOfCriticalPoints[1])$
cr2: ToPoint(ListOfCriticalPoints[2])$
cr3: ToPoint(ListOfCriticalPoints[3])$
cr4: ToPoint(ListOfCriticalPoints[4])$



/*-----------------------------------------------------------------------*/
load(draw); /* ( interface to gnuplot ) by Mario Rodriguez Riotorto http://www.telefonica.net/web2/biomates */

draw2d(
    title = "All  critical orbits for f(z)=z^5 +(0.8+0.4*i)*z^4 + z",
    terminal  = svg,
     user_preamble = "set size square; set key left top;", /* 360/26=13.85  ; 360/(2*26)=6,923 */
    file_name = concat("~/Dokumenty/julia_mse/maxima/04/2/p4_", string(iLength)),
    dimensions  = [1000, 1000],   /* Since Maxima 5.23, pic_width and pic_height are deprecated. */
    /*
    yrange = [-1.0,1.0],
    xrange = [-1.0,1.0],
    */
    xlabel     = "z.re ",
    ylabel     = "z.im",
    
    point_type    = filled_circle,
    points_joined = true,
    
    point_size    = 0.4,
    key="non escaping critical orbit 2",
    color             =light_red ,
    Orbit2,
    point_size    = 1.0,
    key= "critical point 2",
    points_joined = false,
    color           = red,
    cr2,
    
    
    
    key="non escaping critical orbit 3",
    point_size    = 0.4,
    points_joined = true,
    color             =light_blue ,
    Orbit3,
    point_size    = 1.0,
    key= "critical point 3",
    points_joined = false,
    color           = blue,
    cr3,
    
    
    
    key="non escaping critical orbit 4",
    point_size    = 0.4,
    points_joined = true,
    color             =light_green ,
    Orbit4,
    point_size    = 1.0,
    key= "critical point 4",
    points_joined = false,
    color           = green,
    cr4,
    
    
    points_joined = false,
    point_size    = 0.4,
    key="escaping critical orbits",
    color             = light_grey, /* https://maxima.sourceforge.io/docs/manual/maxima_218.html#Item_003a-draw_002fdefvr_002fcolor */
    OrbitEscaping,

    point_size    = 1.0,
    key= "escaping critical point 1",
    color           = light_grey,
    cr1,
    
    point_size    = 1.5,
    point_type    = 9,	
    key= "repelling fixed point",
    color           = light_grey,
    f1,	

    key= "parabolic fixed point",
    color           = magenta,
    f2

 );