Summary

Licensing

Maxima CAS src code

kill(all);
remvalue(all);


/*------------- functions definitions ---------*/

/* function */
f(z):=z^4+m*z;



GiveListOfCriticalPoints(fun):=
block(
  [d,s],
  /* derivative */
  d:diff(fun,z,1),
  /* critical points z: d=0 */
  s:solve(d=0,z),
  /* remove "z="  from list s */
  s:map('rhs,s),
  /* convert to form x+y*%i */
  s:map('rectform,s),
  s:map('float,s),
  return(s)
)$



/* f(z) is used as a global function
   I do not know how to put it as a argument */

GiveOrbit(z0,OrbitLength):=
block(
 [z,Orbit],
 z:z0,
 Orbit:[[realpart(z),imagpart(z)]], 
 for i:1 thru OrbitLength step 1 do
        ( z:expand(f(z)),
          Orbit:endcons([realpart(z),imagpart(z)],Orbit)),
         
 return(Orbit) 

)$

/* find fixed points  returns a list */
GiveFixedPoints():= block
(
  [s],
  s:solve(f(z)=z),
  /* remove "z="  from list s */
  s:map('rhs,s),
  s:map('rectform,s),
  s:map('float,s),
  return(s)
)$



compile(all);

/* ------------  */
fs:string(f(z));
p:3;
q:4;
m:rectform(exp(2*%pi*%i*p/q));
iLength:100000;
s:GiveListOfCriticalPoints(f(z));
multiplicities;
length(s);


Orbits:[];
for i:1 thru length(s) step 1 do
(
 Orbit:GiveOrbit(s[i],iLength),
 Orbits:append(Orbit,Orbits)
);

/*-----------------------------------------------------------------------*/
load(draw); /* ( interface to gnuplot ) by Mario Rodriguez Riotorto http://www.telefonica.net/web2/biomates */
/* http://riotorto.users.sourceforge.net/gnuplot/ps/index.html */

draw2d(
    title = concat("All  critical orbits for discrete map f(z)=",fs ,"  where m=e^{2*pi*i*3/4}= -i "),
    terminal  = png,
    user_preamble = "set angles degrees; set grid polar 15; set xtics 0.62996052494744; set mxtics 0.5; set size square", /* 360/12-30 */
    file_name = concat("~/maxima/parabolic/critical_orbits/z4plusmz/3over4/",string(iLength),"b7"),
    pic_width  = 1000,    /* Since Maxima 5.23, pic_width and pic_height are deprecated. */
    pic_height = 1000,    /* See option dimensions. To get the same effect, write dimensions=[800,600] */
    yrange = [-0.75,0.75],
    xrange = [-0.75,0.75],
    xlabel     = "z.re ",
    ylabel     = "z.im",
    point_type    = filled_circle,
    points_joined = false,
    point_size    = 0.7,
   
    key=" critical orbit ",
    color             =red,
    points(Orbits),
   
    point_size    = 1.2,
    key= "critical points",
    color           = blue,
    points(map(realpart,s),map(imagpart,s)),

    key= "fixed parabolic point",
    color           = black,
    points([[0,0]])

 );

I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.

You are free:

• to share – to copy, distribute and transmit the work
• to remix – to adapt the work

Under the following conditions:

• attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
• share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.

https://creativecommons.org/licenses/by-sa/3.0CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue