# GLSL Programming/Unity/Curved Glass

Crystal balls are examples of curved, transparent surfaces.

This tutorial covers refraction mapping and its implementation with cube maps.

It is a variation of Section “Reflecting Surfaces”, which should be read first.

### Refraction MappingEdit

In Section “Reflecting Surfaces”, we reflected view rays and then performed texture lookups in a cube map in the reflected direction. Here, we refract view rays at a curved, transparent surface and then perform the lookups with the refracted direction. The effect will ignore the second refraction when the ray leaves the transparent object again; however, many people hardly notice the differences since such refractions are usually not part of our daily life.

Instead of the `reflect` function, we are using the `refract` function; thus, the fragment shader could be:

```         #ifdef FRAGMENT

void main()
{
float refractiveIndex = 1.5;
vec3 refractedDirection = refract(normalize(viewDirection),
normalize(normalDirection), 1.0 / refractiveIndex);
gl_FragColor = textureCube(_Cube, refractedDirection);
}

#endif
```

Note that `refract` takes a third argument, which is the refractive index of the outside medium (e.g. 1.0 for air) divided by the refractive index of the object (e.g. 1.5 for some kinds of glass). Also note that the first argument has to be normalized, which isn't necessary for `reflect`.

```Shader "GLSL shader with refraction mapping" {
Properties {
_Cube ("Environment Map", Cube) = "" {}
}
Pass {
GLSLPROGRAM

// User-specified uniforms
uniform samplerCube _Cube;

// The following built-in uniforms
// are also defined in "UnityCG.glslinc",
// i.e. one could #include "UnityCG.glslinc"
uniform vec3 _WorldSpaceCameraPos;
// camera position in world space
uniform mat4 _Object2World; // model matrix
uniform mat4 _World2Object; // inverse model matrix

// Varyings
varying vec3 normalDirection;
varying vec3 viewDirection;

#ifdef VERTEX

void main()
{
mat4 modelMatrix = _Object2World;
mat4 modelMatrixInverse = _World2Object; // unity_Scale.w
// is unnecessary because we normalize vectors

normalDirection = normalize(vec3(
vec4(gl_Normal, 0.0) * modelMatrixInverse));
viewDirection = vec3(modelMatrix * gl_Vertex
- vec4(_WorldSpaceCameraPos, 1.0));

gl_Position = gl_ModelViewProjectionMatrix * gl_Vertex;
}

#endif

#ifdef FRAGMENT

void main()
{
float refractiveIndex = 1.5;
vec3 refractedDirection = refract(normalize(viewDirection),
normalize(normalDirection), 1.0 / refractiveIndex);
gl_FragColor = textureCube(_Cube, refractedDirection);
}

#endif

ENDGLSL
}
}
}
```

### SummaryEdit

Congratulations. This is the end of another tutorial. We have seen:

• How to adapt reflection mapping to refraction mapping using the `refract` instruction.